[vpn-help] Unable to access external sites while VPN connected
Gerd Rothig
gerd.roethig at gmail.com
Tue Oct 22 04:30:33 CDT 2013
As the others already mentioned, it is a Split-Tunnel issue.
That means all traffic from your computer is routed through the VPN, not
only traffic to the internal network.
Has it worked before you upgraded?
There are, basically, two ways to circumvent this problem:
1. Use your company's web proxy. This is the solution your company's
IT will prefer as it will make use of the company's filter for malicious
sites.
2. Specify the networks which you want to be routed through the VPN on
the "Policy" tab on your VPN connection's properties. You first will have to
uncheck "Obtain topology automatically or tunnel all". Afterwards, you can
specify the networks that should be routed through the VPN (example: network
10.0.0.0, netmask 255.0.0.0).
Unfortunately, this second solution does not seem to work anymore (which
might be the cause of your problem).
If it also does not work for you, you will have to set up split tunneling
manually by using a script which hast to be run with administrative
privileges. In that case, you can leave the option "obtain topology
automatically." checked.
This script uses an external configuration file, networks.txt, which simply
contains the networks to be accessed by VPN and their netmasks, each on one
line:
172.16.0.0 255.240.0.0
10.0.0.0 255.0.0.0
Here is the script:
@echo off
rem *****************************************
rem * Setup Split VPN /Split Tunnel *
rem *****************************************
rem network definitions
set NWFILE=networks.txt
rem descriptions
set VPNDESC="Shrew Soft Virtual Adapter"
rem change this to the name of your network card as shown by ipconfig /all
set HOMEDESC="3Com EtherLink 10/100 PCI TX NIC (3C905B-TX) #2"
rem Get VPN Adapter IP Address and home gateway IP address
call :GetIF %VPNDESC% VPNIF
call :GetIP %VPNDESC% IP VPNIP
call :GetIF %HOMEDESC% HOMEIF
call :GetIP %HOMEDESC% gateway HOMEGW
rem reset default route
route delete 0.0.0.0
route add 0.0.0.0 mask 0.0.0.0 %HOMEGW% IF %HOMEIF%
echo Gateway (Home) %HOMEGW%
echo Interface (Home) %HOMEIF%
echo IP-Adresse (VPN) %VPNIP%
echo Interface (VPN) %VPNIF%
rem add routes to VPN network
for /f "tokens=1-2 delims= " %%i in (%NWFILE%) do (
route add %%i mask %%j %VPNIP% IF %VPNIF%
)
goto end
:GetIF
set IF=
setlocal enabledelayedexpansion
set description=%1
set adapterfound=false
for /f "usebackq tokens=1,* delims=." %%f in (`route print 0*^|findstr
/c:%description%`) do (
set /a IF=%%f
)
(
endlocal
set "%2=%IF%"
)
exit /b
:GetIP
set IPADDR=
setlocal enabledelayedexpansion
set description=%1
set addrtype=%2
set adapterfound=false
for /f "usebackq tokens=1-2 delims=:" %%f in (`ipconfig /all`) do (
echo %%g | findstr /c:%description% > nul
if errorlevel 1 (
) else (
set adapterfound=true
)
echo %%f | findstr "%addrtype%" > nul
if errorlevel 1 (
rem Not an IP address
) else (
if !adapterfound!==true (
set IPADDR=%%g
set adapterfound=false
)
)
)
FOR /F "usebackq delims=(" %%i IN (`echo !IPADDR!`) DO (
set IPADDR=%%i
)
(
endlocal
set "%3=%IPADDR%"
)
exit /b
:end
From: vpn-help-bounces at lists.shrew.net
[mailto:vpn-help-bounces at lists.shrew.net] On Behalf Of Walter Sassano
Sent: Monday, October 21, 2013 12:20 AM
To: vpn-help at lists.shrew.net
Subject: [vpn-help] Unable to access external sites while VPN connected
Recently I upgraded my laptop to Windows 8.1 from Windows 8 and also
upgraded my Shrew Soft VPN Client to v. 2.2.2. I am able to connect to my
company's network and have access to all the network resources I expected.
The problem is if I open an browser and navigate to a web site that is not
inside the network, I get a "Page not found" error. As soon as I disconnect
from the network, I have full access to the internet again.
Prior to upgrading I had no issues being connected to the network and
browsing the internet. My laptop has both wired and wireless connections
and both are functional. Does anyone know how to fix this?
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <https://lists.shrew.net/pipermail/vpn-help/attachments/20131022/a5ef6241/attachment-0001.html>
More information about the vpn-help
mailing list